Hi,
I am wondering how it is possible to remove the close button from a form. I want the user to choose one of two buttons I created without the possibility to close the form and not have picked

Regards
Piblon

Removing in effect is actually just disabling it. In design view of the form open the form properties dialog and set Close Button = No. This will disable the button from there and also from the ControlBox as well. To completely remove it from the form you need to set Control Box = No.

Even with these steps there are some that know the CTRL + F4 to close the form and the ATL + F4 to close the application (not to mention the Task Manager). There is a way (via code) of restricting a form from closing until you want it closed.

Kenny Alligood

Thanx

I know that CTRL+F4 and ALT+F4 will close form / application, but the users for my form will probably not use this combination. Nevertheless if nothing else works, I would have to do some coding to disable those functions as well

I happen to read this topic while searching for something else. I have a similar situation where i had restricted the the close event through code. I could'nt find a wayout in VBA to get away with it. (The above mentioned way works fine in VB). Could you please let me know if i m missing some piece of information. I would like to know if that is possible

Ajitpal S Padda

Hi

Just write this code to the Forms QueryClose method:

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then
    Cancel = True
End If
End Sub

vemaju

I am also doing the same thing...but is there a way to get away with cross icon on the right hand side top.

Thanks

Ajitpal S Padda

Hi Guys

I fund this code in a book, and it should do the trick.
The code should be placed in the userforms code module.

'Hide a UserForm's Close Button
'Find the userform's Window
Private Declare Function FindWindow Lib "user32" _
        Alias "FindWindowA" ( _
        ByVal lpClassName As String, _
        ByVal lpWindowName As String) As Long

'Get the current window style
Private Declare Function GetWindowLong Lib "user32" _
        Alias "GetWindowLongA" ( _
        ByVal hWnd As Long, _
        ByVal nIndex As Long) As Long

'Set the new window style
Private Declare Function SetWindowLong Lib "user32" _
        Alias "SetWindowLongA" ( _
        ByVal hWnd As Long, _
        ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long

Const GWL_STYLE = -16
Const WS_SYSMENU = &H80000

Private Sub UserForm_Initialize()
   Dim hWnd As Long, lStyle As Long

   'Which type of userform
   If Val(Application.Version) >= 9 Then
      hWnd = FindWindow("ThunderDFrame", Me.Caption)
   Else
      hWnd = FindWindow("ThunderXFrame", Me.Caption)
   End If

   'Get the current window style and turn off the Close button
   lStyle = GetWindowLong(hWnd, GWL_STYLE)
   SetWindowLong hWnd, GWL_STYLE, (lStyle And Not WS_SYSMENU)
End Sub

Cheers
Karsten