I don't know much about the listview control. I am trying to figure out how to populate the listview with data from a table? I want to add ID, Date, and Desc. The user would then be able to pick what record they want to view.

How would I do this with the following data for example....

ID Date Desc
1 3/31/04 Test1
2 3/29/03 Test2

You can find documentation in the msdn. Select the ListItems property of the ListView control and that gives you this example:

Private Sub Form_Load()
   ' Add ColumnHeaders. The width of the columns is
   ' the width of the control divided by the number of
   ' ColumnHeader objects.
   ListView1.ColumnHeaders. _
   Add , , "Author", ListView1.Width / 3
   ListView1.ColumnHeaders. _
   Add , , "Author ID", ListView1.Width / 3, _
   lvwColumnCenter
   ListView1.ColumnHeaders. _
   Add , , "Birthdate", ListView1.Width / 3
   ' Set View property to Report.
   ListView1.View = lvwReport

   ' Declare object variables for the
   ' Data Access objects.
   Dim myDb As Database, myRs As Recordset
   ' Set the Database to the BIBLIO.MDB database.
   ' IMPORTANT: the Biblio.mdb must be on your
   ' machine, and you must set the correct path to
   ' the file in the OpenDatabase function below.
   Set myDb = DBEngine.Workspaces(0) _
      .OpenDatabase("c:\Program Files\VB\BIBLIO.MDB")
   ' Set the recordset to the "Authors" table.
   Set myRs = _
   myDb.OpenRecordset("Authors", dbOpenDynaset)

   ' Declare a variable to add ListItem objects.
   Dim itmX As ListItem

   ' While the record is not the last record,
   ' add a ListItem object. Use the author field for
   ' the ListItem object's text. Use the AuthorID
   ' field for the ListItem object's SubItem(1).
   ' Use the "Year of Birth" field for the ListItem
   ' object's SubItem(2).

   While Not myRs.EOF
      Set itmX = ListView1.ListItems. _
      Add(, , CStr(myRs!Author)) ' Author.

      ' If the AuthorID field is not null, then set
      ' SubItem 1 to it.
      If Not IsNull(myRs!Au_id) Then
         itmX.SubItems(1) = CStr(myRs!Au_id)
      End If

      ' If the birth field is not Null, set
      ' SubItem 2 to it.
      If Not IsNull(myRs![Year Born]) Then
         itmX.SubItems(2) = myRs![Year Born]
      End If
      myRs.MoveNext ' Move to next record.
   Wend

Thanks!