Calculate Regression/Slope in VB 2008

VBtyler · May 20th, 2009, 07:29 AM

Thanks in advance.

I need to calculate the slope of a regression line through several points within VB 2008.

I have been doing it in VBA with the Excel function, Application.WorksheetFunction.Slope....but can't find anything in VB 2008.

Is there an internal function or something that i can import to do this kind of calculation?

best regards,

VBtyler

Old Pedant · May 21st, 2009, 07:42 PM

Nothing built in, but wouldn't be hard to create your own function to do it.

It's a simple enough formula.

What do your points look like?? That is, are they in array of Point objects or what??

This is TOTALLY off the top of my head:

Code:

Function Slope( pointArray() As Point ) AS Double
    Dim ix As Integer
    Dim avgX As Double = 0
    Dim avgY As Double = 0
    Dim pointCount As Integer = UBound(pointArray)+1
    ' first get the average X and average Y:
    For ix = 0 To pointCount-1
        avgX += pointArray(ix).X
        avgY += pointArray(ix).Y
    Next
    avgX /= pointCount
    avgY /= pointCount
    ' now get the top and bottom sums:
    Dim topSum As Double = 0.0
    Dim bottomSum As Double = 0.0
    For ix = 0 To pointCount-1
        Dim xdiff As Double = pointArray(ix).X - avgX
        topSum += ( xdiff * ( pointArray(ix).Y - avgY ) )
        bottomSum += ( xdiff * xdiff )
    Next
    Return topSum / bottomSum
End Function

That assumes that a Point is described as basically

Code:

Class Point
    public X as Double
    public Y as Double
End Class

Could have other methods, etc., of course.