how can split/replace the <br> with <Para> tags.

moshaik · March 8th, 2009, 05:58 AM

need to split content to '<br>' to <Para> tags. since input content is coming as a text,but not as tag to the xsl. how we can split/replace the <br> with <Para> tags.

input xml content

<table border='1' cellspacing='0'>
<tr>
<td valign="center">first cell <br> after BR <a name='12_0'></a>12.0 end of first td</td>
<td>second cell <a href='#12_4'>12.4</a><br>after br tag second td end</td>
<td>12.4(22)T1<br>12.4(23a)<br>end of thrid td </td>
</tr>
</table>

output XML

<table>
<tr>
<td><Para>first cell </Para>
<Para>after BR <XRef name="12_0"/>12.0 end of first td</Para>
</td>
<td>
<Para>second cell <XRef URL="#12_4">12.4</XRef> </Para>
<Para>after br tag second td end</Para>
</td>
<td>
<Para>12.4(22)T1</Para>
<Para>12.4(23a)</Para>
<Para>end of thrid td </Para>
</td>
</tr>
</table>

Martin Honnen · March 8th, 2009, 11:00 AM

Here is an XSLT 2.0 stylesheet you can use with Saxon 9 or any other XSLT 2.0 processor. Note that it includes the stylesheet http://www.dcarlisle.demon.co.uk/htmlparse.xsl, written by David Carlisle, to parse the escaped HTML (e.g. <br> elements).

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:d="data:,dpc"
  exclude-result-prefixes="d"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:include href="http://www.dcarlisle.demon.co.uk/htmlparse.xsl"/>
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="td">
    <xsl:variable name="phtml">
      <xsl:apply-templates mode="parse"/>
    </xsl:variable>
    <xsl:copy>
      <xsl:for-each-group select="$phtml/node()" group-ending-with="br">
        <Para>
          <xsl:copy-of select="current-group()[not(self::br)]"/>
        </Para>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="a[@name]" mode="parse">
    <XRef name="{@name}"/>
  </xsl:template>
  
  <xsl:template match="a[@href]" mode="parse">
    <XRef URL="{@href}">
      <xsl:apply-templates/>
    </XRef>
  </xsl:template>
  
  <xsl:template match="td/text()" mode="parse">
    <xsl:copy-of select="d:htmlparse(., '', true())"/>
  </xsl:template>
  
</xsl:stylesheet>

Martin Honnen · March 8th, 2009, 11:11 AM

The HTML parser by David Carlisle might be overkill if you are sure it is only escape br elements that are in there. In that case the following XSLT stylesheet should suffice:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="td">
    <xsl:variable name="phtml">
      <xsl:apply-templates mode="parse"/>
    </xsl:variable>
    <xsl:copy>
      <xsl:for-each-group select="$phtml/node()" group-ending-with="br">
        <Para>
          <xsl:copy-of select="current-group()[not(self::br)]"/>
        </Para>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="a[@name]" mode="parse">
    <XRef name="{@name}"/>
  </xsl:template>
  
  <xsl:template match="a[@href]" mode="parse">
    <XRef URL="{@href}">
      <xsl:apply-templates/>
    </XRef>
  </xsl:template>
  
  <xsl:template match="td/text()" mode="parse">
    <xsl:analyze-string select="." regex="&lt;br&gt;">
      <xsl:matching-substring>
        <br/>
      </xsl:matching-substring>
      <xsl:non-matching-substring>
        <xsl:value-of select="."/>
      </xsl:non-matching-substring>
    </xsl:analyze-string>
  </xsl:template>
  
</xsl:stylesheet>