Hi there,
can someone point me to a solution? It is about adding group level to a flat XML using XLST:
I have:
<MyQuotes>
<Quote newpage="true">If u think education is expensive, try ignorance</Quote>
<Quote>Just Do it</Quote>
<Quote>Vorsprung durch Technik</Quote>
<Quote newpage="true">Orandum est ut sit mens sana in corpore sano</Quote>
<Quote>It is all about choices and consequences</Quote>
<Quote newpage="true">What a day to die</Quote>
<Quote newpage="true">Quidquid agis prudenter agas et respice finem</Quote>
<Quote>Wir sind das Volk!</Quote>
<Quote>Dream the Butterfly</Quote>
<MyQuotes>

I want:
<MyQuotes>
<page>
<Quote>If u think education is expensive, try ignorance</Quote>
<Quote>Just Do it</Quote>
<Quote>Vorsprung durch Technik</Quote>
<Quote>Orandum est ut sit mens sana in corpore sano</Quote>
</page>
<page>
<Quote>It is all about choices and consequences</Quote>
</page>
<page>
<Quote>What a day to die</Quote>
</page>
<page>
<Quote>Quidquid agis prudenter agas et respice finem</Quote>
<Quote>Wir sind das Volk!</Quote>
<Quote>Dream the Butterfly</Quote>
</page>
<MyQuotes>

How do I get there?
;) stw
P.S.: Ordered the XLST book, so I can ask smarter questions in future!

If you think education is expensive - try ignorance!

__________________
If you think education is expensive - try ignorance!

Do you mean you want the following:

<MyQuotes>
<page>
<Quote>If u think education is expensive, try ignorance</Quote>
<Quote>Just Do it</Quote>
<Quote>Vorsprung durch Technik</Quote>
</page>
<page>
<Quote>Orandum est ut sit mens sana in corpore sano</Quote>
<Quote>It is all about choices and consequences</Quote>
</page>
<page>

..
..

as <page>Orandum .... has a newpage attribute ??

Exactly. What I need to to is to wrap all quotes into a page element when a newpage=true occurs. The verbal rule:
When you hit a "newpage=true" look for following siblings until the end or the next "newpage=true" (not included) and group them into a <page> element. I can expect that the first element does have a newpage=true... however if a solution wouldn't depend on it would be more robust.
;) stw

If you think education is expensive - try ignorance!

The following code works, but you would have to omit the first instance of newpage="true" to avoid starting with an empty 'page' element.

Obviously I've hardcoded the output tag names, but you could use <xsl:value-of select="local-name()"> to produce a more generic solution.

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output
    method="xml"
    omit-xml-declaration="no"/>

<xsl:template match="/MyQuotes">
<MyQuotes>
    <page>
        <xsl:for-each select="Quote">
            <xsl:choose>
              <xsl:when test="@newpage='true'">
                <xsl:text disable-output-escaping="yes">&lt;/page>&lt;page></xsl:text>
                <Quote><xsl:value-of select="."/></Quote>
              </xsl:when>
              <xsl:otherwise>
                <xsl:copy-of select="." />
              </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </page>
</MyQuotes>
</xsl:template>

</xsl:stylesheet>

holdmykidney

Hi HoldMyKidney,
thx for taking the time to look into my problem. I haven't though using output escaping (feels a bit like cheating). However thx for the solution. I did some reseach just today and found the generic XML solution using generate key:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="MyQuotes">
        <MyQuotes>
            <xsl:apply-templates select="Quote[@newpage='true']"/>
        </MyQuotes>
    </xsl:template>
    <xsl:template match="Quote[@newpage='true']">
        <page>
            <Quote>
                <xsl:value-of select="."/>
            </Quote>

            <xsl:variable name="nextPage" select="generate-id(following-sibling::*[@newpage='true'][1])"/>
            <xsl:apply-templates select="following-sibling::*[generate-id(following-sibling::*[@newpage='true'][1])=$nextPage]"/>
        </page>
    </xsl:template>
    <xsl:template match="Quote[not(@newpage)]">
        <Quote>
            <xsl:value-of select="."/>
        </Quote>
    </xsl:template>
    <xsl:template match="*"/>
</xsl:stylesheet>

David Carlisle and that pages helped: http://www.jenitennison.com/xslt/gro...muenchian.html
;) stw

If you think education is expensive - try ignorance!