Display nodes from xml

nambati · September 16th, 2004, 03:45 PM

Hi,
Please help with this xml and xsl:
---------------------------------------------------------------
<proced>
   <aaa_code V="111">
    <cat>
        <ccc_code V="100"/>
    </cat>
   </aaa_code>
   <aaa_code V="222">
    <cat>
        <ccc_code V="200"/>
        <ccc_code V="100"/>
    </cat>
   </aaa_code>
   <aaa_code V="333">
    <cat>
        <ccc_code V="200"/>
        <ccc_code V="100"/>
    </cat>
   </aaa_code>
</proced>
----------------------------------------------------------------
I want display like this:
--------------------------------
100(ccc_code value)
--------------------------------
    111(aaa_code value)
    222(aaa_code value)
    333(aaa_code value)
------------------------------
200(ccc_code value)
------------------------------
    222(aaa_code value)
    333(aaa_code value)
---------------------------

Here is the XSL I wrote.But this is not displaying 'a_code' node value correctly.
I declared the key on the top:
---------------------------------------------------------------
<xsl:key name="code_duplicate" match="//proced/aaa_code/cat/ccc_code" use="@V"/>

<xsl:for-each select="proced/aaa_code/cat/ccc_code[count(.|key('code_duplicate',@V) [1]) = 1]">
<tr>
   <td>
    <xsl:value-of select="@V"/>
   </td>
</tr>
<tr><td>[u]AAA Code</u></td>
</tr>
    <xsl:for-each select="proced/aaa_code">
       <tr><td>
        <xsl:value-of select="@V"/></td>
       </tr>
    </xsl:for-each>
</xsl:for-each>
----------------------------------------------------------

joefawcett · September 17th, 2004, 03:01 AM

Basically within your outer for-each the context node is ccc_code. To reach the aaa_code node you need the path

Code:

../parent::aaa_code

.
Here's a slightly more refined version that sorts the nodes as well, you may not need that part:

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes"/>
  <xsl:key name="code_duplicate" match="ccc_code" use="@V" />
  <xsl:template match="proced">
    <xsl:for-each select="aaa_code/cat/ccc_code[count(. | key('code_duplicate', @V)[1]) = 1]">
      <xsl:sort select="@V"/>
      <xsl:value-of select="concat(@V, ' (', name(), ' value)' )"/><xsl:text>#xa;</xsl:text>
      <xsl:for-each select="key('code_duplicate', @V)">
        <xsl:sort select="../parent::aaa_code/@V"/>
        <xsl:variable name="current" select="../parent::aaa_code"/>        
        <xsl:text>#x9;</xsl:text>
        <xsl:value-of select="concat($current/@V, ' (', name($current), ' value)' )"/><xsl:text>#xa;</xsl:text>
      </xsl:for-each>     
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

--

Joe (Co-author Beginning XML, 3rd edition)

nambati · September 17th, 2004, 07:57 AM

Hello sir..

Thank you so much.It worked fine.I appreciate your help.