i want to traverse an xml tree using a text file which has values equivalent to the nodes found in the tree. but when i place the this code:
<xsl:param name="file"/>
<xsl:output method="text" omit-xml-declaration="yes" use-character-maps="charmap" encoding="ascii" indent="no"/>
<xsl:strip-space elements="*"/>
<xsl:variable name="elements">
<xsl:analyze-string select="unparsed-text($file,'utf-8')" regex="[\r\n]">
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:template match="livre">
<xsl:apply-templates select="ident"/>
</xsl:template>

<xsl:template match="ident">
<xsl:variable name="node" select="."/>
<xsl:for-each select="$elements">
<xsl:apply-templates select="root($node)/ident/."/>
</xsl:for-each>
</xsl:template>
it outputs the value of the strings. i know that the node-set to be traversed will change upon the use if the xsl:for-each, but is there a way i can do it? thanks. =D

Firstly, this structure:

<xsl:variable name="elements">
  <xsl:analyze-string select="unparsed-text($file,'utf-8')" regex="[\r\n]">
    <xsl:non-matching-substring>
      <xsl:value-of select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:variable>

Goves you a variable whose value is a document node containing the concatenated values of the string. You want to keep the strings separate, so use:

<xsl:variable name="elements" as="xs:string*">
  <xsl:analyze-string select="unparsed-text($file,'utf-8')" regex="[\r\n]">
    <xsl:non-matching-substring>
      <xsl:sequence select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:variable>

or more simply

<xsl:variable name="elements" select="tokenize(unparsed-text($file,'utf-8'), '[\r\n]')"/>

Secondly in this,

<xsl:apply-templates select="root($node)/ident/."/>

you're think that if "." is then string "fred", then the expression is equivalent to

<xsl:apply-templates select="root($node)/ident/fred"/>

which isn't the case for two reasons: firstly, the value of "." changes on the rhs of "/", and secondly, you can't just substitute a value into an expression and have it treated as part of the expression before evaluating the expression - XSLT is an expression language, not a macro language. You want

<xsl:apply-templates select="root($node)/ident/*[name()=current()]"/>



Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference