Hi!

I am usigng XSLT to transform a XML-File to another XML-File. My problem is the nested structure of the elements. In the output file i want to keep the nested structure.

I am new to XSLT and i tried it with named templates, but i didn't solved it.

The element "item" can be nested to a arbitrarily depth. Only the last item can have the attribute src.

The input file looks like this:

<root>
<item title="a">
  <item title="a">
    <item title="a" src="xy"/>
  </item>
</item>
<item title="a" src="xy"/>
<item>
  <item title="a" src="xy"/>
</item>
<othertag/>
</root>

Is it possible to solve this with XSLT 1.0, how?
Thanks for every hint!

You don't actually say what output you want!

Usually this kind of transformation uses an identity template rule:

<xsl:template match="*">
  <xsl:copy>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

which on its own will produce output that is identical to the input. You then typically add further template rules to describe the exceptions, that is elements that should not be copied exactly but modified in some way.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

oh sorry. the output has basically the same structure as the input, but some elements are added (always "addedElement1", excepting the element "item" has no child, then "addedElement2") and the element names are different.


so for example:

<root>
<module title="a">
  <addedElement1/>
  <module title="a">
    <addedElement1/>
    <module title="a" src="xy">
      <addedElement2/>
    </module>
  </module>
</module>
<module title="a" src="xy">
  <addedElement2/>
</module>
<module>
  <addedElement1/>
  <module title="a" src="xy">
    <addedElement2/>
  </module>
</module>
<othertag/>
</root>

So you need a couple of rules like

<xsl:template match="item">
  <module title="{@title}">
    <addedElement1/>
    <xsl:apply-templates/>
  </module>
</xsl:template>

<xsl:template match="item[@src]">
  <module title="{@title}" src="{@src}">
    <addedElement2/>
    <xsl:apply-templates/>
  </module>
</xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

But how do i get the nested structure of the elements? I will need a recursive template call?? Or not?

Did you try the transformation Michael proposed? It is recursive.

--

Joe (Microsoft MVP - XML)

Yes, you need a recursive template call. That's what xsl:apply-templates does.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

I didn't tried it because i missed the root element and thought it couldn't be recursive!
But it works! Thx! Now i understand XSLT a little bit more. Before i always used \\item in the match Attribute of the Template to get all items. But this is completely wrong.

Here is the whole XSLT ... if some newbie also needs it ;)

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">

<xsl:template match="/">
<root>
<xsl:apply-templates/>
</root>
</xsl:template>

<xsl:template match="item">
  <xsl:apply-templates/>
</xsl:template>

<xsl:template match="item">
  <module title="{@title}">
    <addedElement1/>
    <xsl:apply-templates/>
  </module>
</xsl:template>

<xsl:template match="item[@src]">
  <module title="{@title}" src="{@src}">
    <addedElement2/>
    <xsl:apply-templates/>
  </module>
</xsl:template>
</xsl:stylesheet>