Considering the following XSLT:

<xsl:template match="/">
  <xsl:variable name="test" select="true()"/>
  <xsl:choose>
    <xsl:when test="$test">
     <xsl:apply-templates>
       <xsl:with-param name="modify" select="$test"/>
     </xsl:apply-templates>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="list">
  <xsl:param name="modify" />
  <xsl:copy>
   <xsl:if test="$modify">
    do something
   </xsl:if>
  </xsl:copy>
</xsl:template>


The XML:

<document>
  <lists>
    <list>foo</list>
    <list>bar</list>
  </lists>
</document>

For some reason, the parameter is not being passed on to the other templates.

Your template for match="/" applies templates to the children of "/", specifically to the <document> element. There's no explicit template for the <document> element so the default template gets invoked. In XSLT 1.0 this does

<xsl:template match="document">
  <xsl:apply-templates/>
</xsl:template>

It doesn't do:

<xsl:template match="document">
  <xsl:param name="modify"/>
  <xsl:apply-templates>
    <xsl:with-param name="modify" select="$modify"/>
  </xsl:apply-templates>
</xsl:template>

This catches quite a few people out, so the spec has been changed in XSLT 2.0 - in 2.0 the built-in templates do pass parameters through.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

I am sorry, should have provided more information. I am using XSLT 2.0 and saxon8. I was under the impression that 2.0 supports the passing down of parameters through built in template rules.

It works for me. This is the output I get:

<?xml version="1.0" encoding="UTF-8"?>

    <list>
    do something
   </list>
    <list>
    do something
   </list>


That's with 8.9.0.3

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference