Is there any way to perform a global substring replace within a template in such a manner that you are capturing the replaced context as part of a new string, variable, etc rather than simply outputting the new string as its being parsed?

All string-replace template examples I find require spitting the parsed chunks to the output stream as they are identified. I need to be able to do it in such a way that I preserve the new string intact BEFORE it is output. Aren't there some tricks or something for doing this??? Thanks

Yes, you can capture the output of a template in a variable:

<xsl:variable name="temp">
  <xsl:call-template name="string-replace">
    <xsl:with-param...
  </xsl:call-template>
</xsl:variable>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

what in the template populates the variable? Would it be from value-of element? For instance, what I see are templates like (below), where the value-of streams to the output as the string is parsed. If I wrapper the (below) in a variable definition, will the value-of output build the variable string as opposed to streaming to output?

<xsl:template name="globalReplace">
        <xsl:param name="outputString"/>
        <xsl:param name="target"/>
        <xsl:param name="replacement"/>
        <xsl:choose>
            <xsl:when test="contains($outputString,$target)">
                <xsl:value-of select="concat(substring-before($outputString,$target),
               $replacement)"/>
                <xsl:call-template name="globalReplace">
                    <xsl:with-param name="outputString" select="substring-after($outputString,$target)"/>
                    <xsl:with-param name="target" select="$target"/>
                    <xsl:with-param name="replacement" select="$replacement"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$outputString"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

The xsl:variable (with content instructions) creates the root of a temporary tree, and all instructions within its dynamic scope that create nodes then write those nodes to the temporary tree instead of to the final output tree. That includes xsl:value-of, which writes a text node.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks! That is a new wrinkle to my understanding of xslt. Now things work as I had hoped. Many Thanks!