Hello all,

I'm trying to remove spaces (both whitespaces and others) from <book> elements with the given conditions:

1) if <book> has a child element <topic>programming<topic> then spaces in all its child elements be removed. Point to note here is that both preceding, trailing and spaces in between elements/nodes and text be removed.

2) If <book> has a child element <topic>Literature<topic> then ALL spaces EXCEPT where preceding child<name> has value "Lang*" should be removed.

Before:

<books>
 <book>
  <topic>programming</topic>
   <title> Learn XML </title>
    <chapters>AL L
     <name> Introduction</name> <name> varia bles</name> </chapters>
  </book>
  <book>
   <topic>Literature</topic>
    <title> something </title>
     <chapters>Ne w<name> Introduction</name>
      <name> Engli sh</name> Language
      <name> variables</name> </chapters>
   </book>
<books>

AFTER:
<books>
 <book>
  <topic>programming</topic>
   <title>Learn XML</title>
    <chapters>ALL<name>Introduction</name>
    <name>variables</name></chapters>
  </book>
  <book>
   <topic>Literature</topic>
    <title> something</title>
     <chapters>New<name>Introduction</name>
     <name>Engl ish</name>Language<name> variables</name>
     </chapters>
   </book>
<books>

So, in the given example all spaces except one with "variables" is removed. Please let me know if this can be done.

Thanks,
Trishla

I normally use "whitespace" to mean x9, xA, xD, and x20, and "space" to mean just x20, so I first have to understand what you mean by the terms...

From your rules, I can't see why the space was left in "Engl ish" as in

<name>Engl ish</name>Language<name> variables</name>

Looks to me something like this (this is 2.0):

(a) an identity template

<xsl:template match="*" mode="#all">
  <xsl:copy><xsl:apply-templates mode="#current"/></xsl:copy>
</xsl:template>

(b) A rule for the cases where you want to strip all spaces:

<xsl:template match="book[topic='programming']">
  <xsl:copy><xsl:apply-templates mode="strip-all"/></xsl:copy>
</xsl:template>

<xsl:template match="text()" mode="strip-all">
  <xsl:value-of select="translate(., ' ', '')"/>
</xsl:template>

(c) A rule for the cases where you want to strip some spaces:

<xsl:template match="book[topic='Literature']">
  <xsl:copy><xsl:apply-templates mode="strip-some"/></xsl:copy>
</xsl:template>

<xsl:template match="text()[not(starts-with(preceding::text()[1], 'Lang')" mode="strip-some">
  <xsl:value-of select="translate(., ' ', '')"/>
</xsl:template>


With 1.0, the only difference is that rule 1 needs to be written three times, once for each mode.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thank you so much for replying...

Yeah, that was typo..there should be no space in "English"

But the template match for strip-some mode says "Invalid xpath expression, when I try to transform with the exact code you suggested.

Also, when you say with ver 1.0 rule 1 need to be written 3 times for each mode then what is rule 1 here? I'm using ver 1.0.

Thanks,
Trishla

He is refering to :

<xsl:template match="*" mode="#all">
  <xsl:copy><xsl:apply-templates mode="#current"/></xsl:copy>
</xsl:template>

In XSLT 1.0 the mode="#all" and mode="#current" are not supported, so you would have to create three copies of this no mode, one with mode="strip-all" and one with mode="strip-some".

/- Sam Judson : Wrox Technical Editor -/

Yes, there's a missing closing "]", but I assume you found that without my help.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Yup, that I corrected but still the output file is not well formed. could it be because I don't have correct version?

I'm using XMLSpy® 5 Professional Edition Rel. 2 and don't know whether it supports 2.0 or not. And I'm not able to get it correct for ver 1.0 by making changes as suggested here. So, all this for sure proves that I'm a newbie and way to go.

Thanks again.
Trishla

I'm getting output exactly same as input...would appreciate any response/comments. Here is what I did to make it work for 1.0

XSLT Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:template match="*">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*" mode="strip-all">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*" mode="strip-some">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="book[topic='programming']">
        <xsl:copy>
            <xsl:apply-templates mode="strip-all"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text()" mode="strip-all">
        <xsl:value-of select="translate(., ' ', '')"/>
    </xsl:template>
    <xsl:template match="book[topic='Literature']">
        <xsl:copy>
            <xsl:apply-templates mode="strip-some"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text()[not(starts-with(preceding::text()[1], 'Lang'))]" mode="strip-some">
        <xsl:value-of select="translate(., ' ', '')"/>
    </xsl:template>
</xsl:stylesheet>


Input XML is:

<?xml version="1.0" encoding="UTF-8"?>
<books>
    <book>
        <topic>programming</topic>
        <title> Learn XML </title>
        <chapters>AL L
     <name> Introduction</name>
            <name> varia bles</name>
        </chapters>
    </book>
    <book>
        <topic>Literature</topic>
        <title> something </title>
        <chapters>
            <name> Introduction</name>
            <name> Engli sh</name>Language<name> variables</name>
        </chapters>
    </book>
</books>

And the output is exactly same ...no spaces trimmed.

got it working...Big thanks to all who responded..I really appreciate all help.

but wait...I'll be posting more question here and bugging everybody :) in coming days

These two templates need to continue in the current mode:

    <xsl:template match="*" mode="strip-all">
        <xsl:copy>
            <xsl:apply-templates mode="strip-all"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*" mode="strip-some">
        <xsl:copy>
            <xsl:apply-templates mode="strip-some"/>
        </xsl:copy>
    </xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference