XSLT for parsing XHTML Form

shahbhat · August 22nd, 2008, 11:56 AM

I am writing a proxy server that is going to parse all forms such that they go through the proxy server and add a few hidden form fields, e.g.
If I have the XHTML that has form like
<form id=".." name=".." action="/dosomething" method="post">

I would like to parse it so that I can store the
action and method attributes in my session and change the form to
<form id=".." name=".." action="/myserver" method="post">
<input type="hidden" name="myfield" value="value"/>
...

I am thinking about using XSL for this, but not sure if it's easy enough, basically I want to do following:
1. parse XHTML forms and store form name/action/method to my session
2. change action attribute (the exact path will be generated dynamically).
3. I want to copy all attributes of form as they are except action/method.
4. add hidden fields

Is this easily doable in XSL, alternatively I can just parse XHTML as XML and create my own XHTML output.

Martin Honnen · August 22nd, 2008, 12:24 PM

You can easily do 2, 3 and 4 with XSLT:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:xhtml="http://www.w3.org/1999/xhtml"
  xmlns="http://www.w3.org/1999/xhtml"
  exclude-result-prefix="xhtml">

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="xhtml:form">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="action">/myserver</xsl:attribute>
      <input type="hidden" name="myfield" value="value"/>
      <xsl:apply-templates select="node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

1 (storing "form name/action/method to my session") will require use of an extension object or function.

--
Martin Honnen
Microsoft MVP - XML

shahbhat · August 22nd, 2008, 12:48 PM

Thanks Martin, that will get me started. Regarding #1, I am using Java so I am not sure if the APIs support callback functions but I will look into it.

shahbhat · August 22nd, 2008, 04:58 PM

I noticed following error when running it through Java XSLT transformer:
line 16: Attribute 'action' outside of element.

It seems like it is complaining about
<xsl:attribute name="action">/myserver</xsl:attribute>

Any idea? Also, I would like to skip some of XHTML tags such as <html>, <title>. I think I can just match for those tags and not emit any output, but is there a better way. Thanks again.

Martin Honnen · August 23rd, 2008, 08:05 AM

I typed my stylesheet directly in the forum editor without testing it.
However when testing now I find that the only error is naming the attribute exclude-result-prefix instead of exclude-result-prefixes.
So the following correction should work fine:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:xhtml="http://www.w3.org/1999/xhtml"
  xmlns="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="xhtml">

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="xhtml:form">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="action">/myserver</xsl:attribute>
      <input type="hidden" name="myfield" value="value"/>
      <xsl:apply-templates select="node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

When applied to the input XHTML

Code:

<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>Example</title>
</head>
<body>
<form id=".." name=".." action="/dosomething" method="post">
<input type="text" name="foo"/>
<input type="submit"/>
</form>
</body>
</html>

the result with Saxon 6.5 is

Code:

<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>Example</title>
</head>
<body>
<form id=".." name=".." action="/myserver" method="post"><input xmlns:xhtml="http://www.w3.org/1999/xhtml" type="hidden" name="myfield" value="value"/>
<input type="text" name="foo"/>
<input type="submit"/>
</form>
</body>
</html>

I am not sure why you get the error you mention, sounds as if you have moved an instruction to create an attribute to a position where it is not allowed to create an attribute.

As for not copying certain elements, if you want to remove the title element you only need to add the template

Code:

<xsl:template match="xhtml:title"/>

If you don't want to emit an html element then you need to add

Code:

<xsl:template match="xhtml:html">
  <xsl:apply-templates/>
</xsl:template>

that makes sure the element is not copied but its children are processed.

--
Martin Honnen
Microsoft MVP - XML

mhkay · August 24th, 2008, 11:08 AM

There's nothing wrong with that xsl:attribute instruction in itself, but you are probably issuing it in a context where you can't output attributes - for example, after outputting a child element.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

shahbhat · August 26th, 2008, 06:22 PM

Thanks Martin and Michael again, though I am still getting warning about "outside of element" but transformation is working.