Extracting ancestor by providing the attribute

eruditionist · September 5th, 2008, 04:12 PM

Here is my xml

<node id="fkh489a3">
    <node id="fkh489e4">
     <label key="">John</label>
    </node>
    <node id="fkh489e5">
     <label key="">Charles</label>
    </node>
    <node id="fkh489e6">
     <label key="">Smith</label>
    </node>
</node>

I have one of the //node/node id specified which is fkh489e4. How can I use this id to print the label (John, Charles, Smith)?
This is what im trying right now and it only prints John but not the rest of the labels can someone tell me what im doing wrong and how to print all the labels? I must print the labels using the ID I have. thanks.

<xsl:for-each select="//node/node[@id = 'fkh489e4']/preceding-sibling::*">
<br/>
<xsl:value-of select="/node/label"/><br/>

</xsl:for-each>

mhkay · September 5th, 2008, 05:13 PM

I don't see how this code can possibly "print" anything since (a) there is no element selected by /node/label (that's an absolute path expression that selects from the root of the tree), and (b) the node with id fkh489e4 has no preceding siblings.

It seems to me you want

<xsl:for-each select="//node[node/@id ='fkh489e4']/node">
<br/>
<xsl:value-of select="label"/><br/>

That should work on this example, but you haven't explained the general problem very well so I might have misunderstood your intentions.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

joefawcett · September 6th, 2008, 04:45 AM

I added an element to your XML:

Code:

<data>
  <node id="fkh489a3">
    <node id="fkh489e4">
      <label key="">John</label>
    </node>
    <node id="fkh489e5">
      <label key="">Charles</label>
    </node>
    <node id="fkh489e6">
      <label key="">Smith</label>
    </node>
  </node>
</data>

Then this XSLT does what you want:

Code:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:param name="id" select="'fkh489e4'" />
  <xsl:template match="/*">
    <name>
      <xsl:for-each select="node[node[@id = $id]]">
        <xsl:apply-templates select="node" />
      </xsl:for-each>
    </name>
  </xsl:template>

  <xsl:template match="node/node">
    <xsl:value-of select="label"/>
    <xsl:if test="position() != last()">
      <xsl:text>, </xsl:text>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

--

Joe (Microsoft MVP - XML)

eruditionist · September 8th, 2008, 09:26 AM

thanks Kay it worked

eruditionist · September 8th, 2008, 10:05 AM

Can I do this ? whats the correct syntax? so I can put pageLink2 in document.write

<script type="text/javascript">
var pageLink2="abc1234";
document.write(<xsl:for-each select="//node/node[@id ='"+pageLink2+"']">
<xsl:value-of select="label"/>
</xsl:for-each>);
</script>

mhkay · September 8th, 2008, 12:13 PM

You seem to be muddled about whether you are nesting XPath inside Javascript or vice versa. The obvious answer is that

<xsl:for-each select="//node/node[@id ='"+pageLink2+"']">

isn't well-formed XML so you can't write it. But more subtly, you are generating a <script> element in the target HTML page, which will execute when the page loads and perhaps when the user clicks on some button, and yet you seem to be trying to use the value of the Javascript variable during the transformation. If I have misunderstood what you are trying to do, sorry - it's hard to guess what people intended when the syntax is incorrect.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

eruditionist · September 9th, 2008, 08:12 AM

no problem I didnt think it was possible I will have to approach this problem differently. thanks again.