Hi!

I'm trying to use a template with a param, but it doesn't seem to work when using apply-templates. Earlier I'm only used call-template with-params, but now that won't do.

<xsl:apply-templates>
                            <xsl:with-param name="someparam">somevalue</xsl:with-param>
 </xsl:apply-templates>

 <xsl:template match="//node">
     <xsl:param name="someparam"/>
          <xsl:value-of select="$someparam"/>
    </xsl:template>


This won't work. Why? How could I make it working?

It works. Just show the input xml and some more xsl.

------
Rummy

The most likely explanation is that your apply-templates call isn't invoking the template rule directly, but indirectly via a built-in template for some intermediate element. The built-in templates in XSLT 1.0 don't pass the parameters on (this has changed in XSLT 2.0). The solution is to supply an explicit template rule for the intermediate element nodes.


Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

Are you using XSLT 2.0?

Well, in terms of this problem the structure is as simple as this:

Hmm... A built-in element? So in what kind of a context would the call happen directly without losing the passed parameter? Why doesn't XSLT 1.0 pass the parameter by default? Isn't it always needed?

So how is this done in practice?

You haven't shown your XML. If it's like this:

<a>
  <b>
    <c/>
  </b>
</a>

and your template rules are

<xsl:template match="a">
  <xsl:apply-templates>
    <xsl:with-param name="x">23</xsl:with-param>
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="c">
  <xsl:param name="x".../>
</xsl:template>

then the apply-templates call selects the b element, there is no template rule for the b element, so the built-in template rule is invoked, this applies-templates to the c element, but without passing the parameters on. The solution is to add a template rule

<xsl:template match="b">
  <xsl:param name="x"/>
  <xsl:apply-templates>
    <xsl:with-param name="x" select="$x"/>
  </xsl:apply-templates>
</xsl:template>

or to make the call direct:

<xsl:template match="a">
  <xsl:apply-templates select="b/c">
    <xsl:with-param name="x">23</xsl:with-param>
  </xsl:apply-templates>
</xsl:template>

>Why doesn't XSLT 1.0 pass the parameter by default?

Probably an oversight by the language designers. W3C did things a lot more quickly in those days and there wasn't so much time for review. XSLT 2.0 fixes many such usability problems.

Michael Kay
http://www.saxonica.com/
Author, XSLT 2.0 and XPath 2.0 Programmer's Reference

Ah, sorry. I somehow didn't notice that mrame asked for also that (not only xsl).


Thanks! That was a very clear explanation to the reason behind the problem. And now it works, when I use the direct call! :)

Okay. It's more understandable now that I learned from your example that it practically makes these intermediary template-calls when there are no direct matches.