Filtering XML Elements using XSLT.

alapati.sasi · March 23rd, 2009, 04:14 AM

Hi All,

i have a requirement to filter xml elements .
For eg:-
If my input is :-
<root>
<a/>
<b/>
<c/>
</root>
In this after applying xslt i need to filter some elements .

For example dynamically i will know "b & c" elements needs to be filtered and my final xml should be something like this .

<root>
<a/>
</root>

Is it possible to do so using xslt .

Please help me in this .

Regards,
Sasi.A

JohnBampton · March 23rd, 2009, 06:39 AM

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"
      version="2.0">
    <xsl:template match="root">
        <xsl:copy>
            <xsl:apply-templates select="a"></xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="a">
        <xsl:copy-of select="."></xsl:copy-of>
    </xsl:template>
</xsl:stylesheet>

Cheers, John Bampton.

alapati.sasi · March 23rd, 2009, 11:22 AM

Hi John,
Thanks for your help .
I have one more small doubt, If "a &b" elements are dynamic for me i.e suppose a & b are not static for me , I will get some element names dependind upon some selection and those elements should be there in the final xml .

In this case user will select a & b elements and i will get that info and the original xml file and then i need to apply for filtering of all the other elements except the elements i got from the user.

I hope i am clear .

Once again thanks for your valuable reply.

Regards,
Sasi.A

Martin Honnen · March 23rd, 2009, 11:30 AM

Which XSLT processor do you use? Do you use XSLT 1.0 or 2.0?
If you get element names 'a' and 'b', do you want to remove elements with those names? Or do you want to remove elements with names different from 'a' and 'b'?

Martin Honnen · March 23rd, 2009, 11:52 AM

Here is an example using XSLT 2.0 which assumes you pass in a parameter named to-delete which is a sequence of local names to be deleted:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:strip-space elements="*"/>
  
  <xsl:param name="to-delete" as="xs:string*"/>
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="*[local-name() = $to-delete]"/>

</xsl:stylesheet>

For instance, using AltovaXML tools, you could run that as follows to delete elements named 'a' and 'c':
AltovaXML.exe /xslt2 sheet.xsl /in file.xml /param to-delete="('a', 'c')"

Martin Honnen · March 23rd, 2009, 11:56 AM

As an alternative, if you want to pass in element names you want to copy, here is an example that takes element names to be copied as the parameter to-copy as a sequence of strings:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:strip-space elements="*"/>
  
  <xsl:param name="to-copy" as="xs:string*"/>
  
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="/*/*[not(local-name() = $to-copy)]"/>

</xsl:stylesheet>

It assumes you pass in names of child element names of the root element which you want to copy.