copying namespace question

JohnBampton · March 30th, 2009, 11:31 AM

I have the following input xml

Code:

<ProjectX>
    <Agent_Class>xNETports</Agent_Class>
</ProjectX>

and I need this output xml

Code:

<ProjectX xmlns="http://www.mynamespace.com">
      <Agent_Class>xNETports</Agent_Class>
</ProjectX>

I am using this xsl

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"
      version="2.0">
    <xsl:output method="xml" indent="yes"></xsl:output>
    <xsl:template match="ProjectX">
        <ProjectX xmlns="http://www.mynamespace.com">
            <xsl:apply-templates select="@*|node()" />
        </ProjectX>
    </xsl:template>
    <xsl:template match="*" >
        <xsl:copy-of select="."></xsl:copy-of>
    </xsl:template>
</xsl:stylesheet>

but i get the following xml instead

Code:

<ProjectX xmlns="http://www.mynamespace.com">
      <Agent_Class xmlns="">xNETports</Agent_Class>
</ProjectX>

how do i remove the xmlns="" from the Agent_Class element??

Martin Honnen · March 30th, 2009, 11:39 AM

In your input XML all elements are no namespace, in your desired result all elements are in that namespace http://www.mynamespace.com. So your stylesheet needs to transform all elements to the new namespace e.g.

Code:

<xsl:template match="*">
  <xsl:element name="{local-name()}" namespace="http://www.mynamespace.com">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

mhkay · March 30th, 2009, 11:52 AM

>how do i remove the xmlns="" from the Agent_Class element?

You need to think about the result tree produced by the transformation, not about the lexical XML produced by the serializer. The serializer is outputting the xmlns="" because in the result tree, the Agent_Class element node is in no namespace. So you need to change your code so it doesn't put the Agent in a namespace. That means the Agent_Class node is not an exact copy of what's in the input (it has a different name!), so you can't create it using xsl:copy-of.