Look up an ancestors attribute from a for-each-group

bonekrusher · July 13th, 2009, 10:29 AM

Hi, I am creating a back-of-the-book index which will result in an xsl-fo document. I am using grouping for my index. I am grouping on <indxref> and need get the closest @id from an ancestor. How can I do this with grouping?

Thanks

XML

Code:

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <chapter id="chapter1">
        <title id="title">
            <indxref indxlevel1="Stopping Procedures"/>
            <indxref indxlevel1="Procedures, Stopping"/>                 
        </title>
    </chapter>
   
</root>

XSLT

Code:

 <xsl:for-each-group select="//indxref" group-by="substring(@indxlevel1, 1,1)">
        <xsl:sort select="current-grouping-key()" order="ascending"/>
        <xsl:variable name="curID">
            <xsl:for-each select="ancestor::*[@id]">
                <xsl:if test="position() = last()">
                    <xsl:value-of select="@id"/>
                </xsl:if>
            </xsl:for-each>
        </xsl:variable>
    </xsl:for-each-group>

Martin Honnen · July 13th, 2009, 10:39 AM

Can you show us the result you want to get from the XML input you have posted?
Inside of the xsl:for-each-group the context node is the first item in each group so your code doing ancestor::*[@id] would look at the ancestor elements of the first item in each group. Note however that the closest ancestor in my understanding would be the first element on the ancestor axis as that is a reverse axis. So you could simply do

Code:

<xsl:variable name="curID" select="ancestor::*[@id][1]/@id"/>

bonekrusher · July 13th, 2009, 11:07 AM

Thanks for the help.

Code:

<xsl:variable name="curID" select="ancestor::*[@id][1]/@id"/>

This returns the first <indxref> ancestor::*[@id][1]/@id. Below is a working example.

Current output:

Code:

<out xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <result>title</result>
    <result>title</result>
</out>

Code:

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <chapter id="chapter1">
        <title id="title">
            <indxref indxlevel1="Stopping Procedures">
                <pcnarr>STOPPING PROCEDURE</pcnarr>
            </indxref>
            <indxref indxlevel1="Procedures, Stopping">
                <pcnarr/>
            </indxref>
        </title>
    </chapter>
    <chapter id="chapter2">
        <title id="title2">
            <indxref indxlevel1="Procedures">
                <pcnarr> PROCEDURE</pcnarr>
            </indxref>
            <indxref indxlevel1="Procedures, running">
                <pcnarr/>
            </indxref>
        </title>
    </chapter>
</root>

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <out>
            <xsl:for-each-group select="//indxref" group-by="substring(@indxlevel1, 1,1)">
                <xsl:sort select="current-grouping-key()" order="ascending"/>                
                <xsl:variable name="curID" select="ancestor::*[@id][1]/@id"/>
                <result>
                    <xsl:value-of select="$curID"/>
                </result>
            </xsl:for-each-group>
        </out>
    </xsl:template>
</xsl:stylesheet>

I am using saxon 9.1.0.5

My desired result would be:

Code:

<out xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <result>title</result>
    <result>title</result>
    <result>title2</result>
    <result>title2</result>
</out>

samjudson · July 13th, 2009, 11:12 AM

You need an inner for-each on the current group otherwise you are just looping once per group, not once for each item in the group:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
   <xsl:template match="/">
       <out>
           <xsl:for-each-group select="//indxref" group-by="substring(@indxlevel1, 1,1)">
               <xsl:sort select="current-grouping-key()" order="ascending"/>
               <xsl:for-each select="current-group()">
               <xsl:variable name="curID" select="ancestor::*[@id][1]/@id"/>
               <result>
                  <xsl:value-of select="$curID"/>
               </result>
               </xsl:for-each>
           </xsl:for-each-group>
       </out>
   </xsl:template>
</xsl:stylesheet>

Martin Honnen · July 13th, 2009, 11:27 AM

You might not need the xsl:for-each-group then:

Code:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <out>
            <xsl:for-each select="//indxref">
                <xsl:sort select="substring(@indxlevel1, 1,1)"/>
                <result>
                      <xsl:value-of select="ancestor::*[@id][1]/@id"/>
                </result>
            </xsl:for-each>
        </out>
    </xsl:template>
</xsl:stylesheet>

bonekrusher · July 13th, 2009, 12:08 PM

Thanks Martin and Sam.

Sam's solution will work as I am actually doing multi-grouping.

Thanks for all the help.

Phil