Efficiently Breaking Out of Parent

AForgue · December 23rd, 2003, 09:40 AM

Following is the source XML that I am transforming. As you can see, the <text:a> tag is a child of the <text:p> tag:

Code:

<text:p text:style-name="Dog_Normal">
   ...the one hand, the national economy had performed...
   <text:a xlink:type="simple" xlink:href="http://www.atomicdog.com/" office:name="Name" office:target-frame-name="_blank" xlink:show="new">prowess</text:a>
   ... or his ability to ...
</text:p>

According to my companies DTD, the XML containing links should not be nested in paragraph text nodes. So ideally, I would like to transfrom the above XML into this:

Code:

<Dog_Normal>
   ...the one hand, the national economy had performed...
</Dog_Normal>
<Dog_Link>
   <Dog_URL>http://www.atomicdog.com/</Dog_URL>
   <Dog_Reference>prowess</Dog_Reference>
</Dog_Link>
<Dog_Normal>
   ... or his ability to ...
</Dog_Normal>

So my question is, is there an efficient way of "breaking the parent" of the context node? So far I have had a rough time with thinking of a way to do this. My first instinct was to do something like this:

Code:

<xsl:template match="<text:a>">
   </Dog_Normal>
   <Dog_Link>...</Dog_Link>
   <Dog_Normal>
</xsl:template>

However, this is malformed XML and does not pass the parser. Any thoughts?

Thanks in advance!
Aaron

armmarti · December 24th, 2003, 11:52 AM

I suppose that this stylesheet is applied to the XML snippet you posted(as a separate XML document).
I suppose also that all namespace prefixes are properly bound to their namespace URIs:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:text="TEXT" xmlns:xlink="XLINK" xmlns:office="OFFICE" exclude-result-prefixes="text xlink office">
    <xsl:output indent="yes"/>
    <xsl:template match="text:p">
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="text()[parent::text:p]">
        <xsl:element name="{../@text:style-name}">
            <xsl:value-of select="."/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="text:a">
        <Dog_Link>
            <Dog_URL><xsl:value-of select="@xlink:href"/></Dog_URL>
            <Dog_Reference><xsl:value-of select="."/></Dog_Reference>
        </Dog_Link>
    </xsl:template>
</xsl:stylesheet>

If you need to "insert" these template rules to existing stylesheet, you have to be careful: do not let any "interference". If you'll have troubles with that, let me know.

Regards,
Armen