Grouping following siblings

bonekrusher · November 19th, 2009, 12:29 PM

Hi,

I am not sure how I should approach this problem. I am trying to group <para>'s based on values. for example, in this sample xml file:

Code:

<book>
    <para config="start">start first</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="end">first group end</para>
    <para>data</para>
    <para>data</para>
    <para config="start">start second</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="end">second group end</para>
    <para>data</para>
    <para>data</para>
    <para>data</para>
    <para config="start">start end</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="middle">data</para>
    <para config="end">third group end</para>
    <para>data</para>
    <para>data</para>
    <para>data</para>
</book>

I want to group each para by the @config attribute (start, beginning and end).

desired output:

Code:

<book>
    <table>
        <para>first group end</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>first group end</para>
    </table>
    <para>data</para>
    <para>data</para>
    <para/>
    <table>
        <para>second group end</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>second group end</para>
    </table>
    <para>data</para>
    <para>data</para>
    <para>data</para>
    <table>
        <para>third group end</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>data</para>
        <para>third group end</para>
    </table>
    <para>data</para>
    <para>data</para>
    <para>data</para>
</book>

Here is my xslt so far, which does not work. Should or could I use the for-each-group ?

Code:

    <xsl:template match="para">
        <xsl:choose>
            <xsl:when test="@config='start'">
                <xsl:if test="@config='start'">
                    <xsl:element name="para">
                        <xsl:apply-templates select="self::*[para][1]" />
                    </xsl:element>
                </xsl:if>
                <table>
                    <xsl:for-each select="following-sibling::para[@config='mid']">
                        <xsl:comment>Para is mid</xsl:comment>
                        <xsl:element name="para">
                            <xsl:apply-templates/>
                        </xsl:element>
                    </xsl:for-each>
                    <xsl:if test="following-sibling::para[@config='end'][1]">
                        <xsl:for-each select="following-sibling::para[@config='end'][1]">
                            <xsl:element name="para">
                                <xsl:apply-templates/>
                            </xsl:element>
                        </xsl:for-each>
                    </xsl:if>
                </table>
            </xsl:when>
            <xsl:otherwise>
                <xsl:element name="para">
                    <xsl:apply-templates/>
                </xsl:element>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

Martin Honnen · November 19th, 2009, 12:45 PM

Yes, you can use for-each-group group-adjacent as follows:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="book">
    <xsl:copy>
      <xsl:for-each-group select="para" group-adjacent="@config = 'middle'">
        <xsl:choose>
          <xsl:when test="current-grouping-key()">
            <table>
              <xsl:apply-templates select="preceding-sibling::para[@config = 'start'][1], current-group(), following-sibling::para[@config = 'end'][1]"/>
            </table>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="current-group()[not(self::para[@config = 'start']) and not(self::para[@config = 'end'])]"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>
 
  <xsl:template match="para">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

bonekrusher · November 19th, 2009, 01:52 PM

Thanks Martin,

Is it possible to have the for-each-group inside my para template. The actually document would need the condition to be applied in the template because the para element is called from an infinite number of different parent elements. In the example, its just book, but for my actually project I would hopefully like to have the condition in the para template.

Thanks for the help

Martin Honnen · November 19th, 2009, 02:07 PM

You need to group the 'para' elements in the template of the parent. If you have several possible parents then just do

Code:

<xsl:template match="book | foo | bar">...</xsl:template>

where 'book', 'foo' and 'bar' are the names of possible parent elements of the 'para' elements.
Hmm, you say it is an infinite numer of different parent element. In that case maybe

Code:

<xsl:template match="*[para]">...</xsl:template>

will do.
Doing the grouping inside a template for a 'para' element is not really suitable unless you tell us which 'para' element is supposed to perform the grouping.

Martin Honnen · November 19th, 2009, 02:19 PM

If you really want the xsl:for-each-group inside a template for 'para' then the following groups for the first 'para' child:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="para[1]">
    <xsl:for-each-group select="../para" group-adjacent="@config = 'middle'">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <table>
            <xsl:apply-templates select="preceding-sibling::para[@config = 'start'][1], current-group(), following-sibling::para[@config = 'end'][1]" mode="m1"/>
          </table>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="current-group()[not(self::para[@config = 'start']) and not(self::para[@config = 'end'])]" mode="m1"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:template>
  
  <xsl:template match="para"/>
 
  <xsl:template match="para" mode="m1">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

bonekrusher · November 19th, 2009, 02:30 PM

Thanks a bunch