XLST noob - XML -> XML transform help required

Crass1968 · March 4th, 2010, 05:33 AM

Just had this dropped on me and I have almost zero experience with XLST.
I need to convert the following XML...

<Outer>
<A>Contains lots of child nodes</A>
<A>Contains lots of child nodes</A>
<A>Contains lots of child nodes</A>

<MainNode>
Contains lots of child nodes
</Mainnode>

</Outer>

Convert to.....

<Outer>
<MainNode>
Contains lots of child nodes
<A>Contains lots of child nodes</A>
<A>Contains lots of child nodes</A>
<A>Contains lots of child nodes</A>

</Mainnode>

</Outer>

Basically, I want to move all the <A> nodes that precede each <MainNode>, inside the <Mainnode> as children nodes of it. There can be many <A> nodes for each <MainNode> of which there may also be many.

As I say I am virtually a complete newbie to XSLT but do not wish to be spoonfed and answer as I won't learn anything from it. Psuedocode, hints of the keywords or useful links would be much appreciated though.
I know I am going to be using xsl:For-each, xsl:copy-of, etc but do not know how to structure this.

Thanks

mhkay · March 4th, 2010, 05:45 AM

>Basically, I want to move all the <A> nodes that precede each <MainNode>, inside the <Mainnode> as children nodes of it.

That sort of hints that there might be <A> nodes that don't precede the MainNode, though your example doesn't show any.

Anyway, there are basically two rules here:

(a) if you find an A node before a MainNode, drop it

Code:

<xsl:template match="A[following-sibling::MainNode]"/>

(b) if you find a MainNode, copy its contents followed by all the preceding A nodes

[code]
<xsl:template match="MainNode">
<MainNode>
<xsl:copy-of select="child::node()"/>
<xsl:copy-of select="preceding-sibling::A"/>
</MainNode>
</xsl:template>
[code]

>I know I am going to be using xsl:For-each,

No: try to avoid xsl:for-each. Try to structure your code in terms of rules: "why I hit an XXX element, what should I do with it?"

samjudson · March 4th, 2010, 06:02 AM

Assuming that the <A> and <MainNode> elements keep repeating then you need to identify <A> elements that precede a <MainNode>, but stop at the last <MainNode>

To get all the preceding <A> elements you can use the following XPATH: preceding-sibling::A

This will however not stop at the previous <MainNode> element. One way to solve this would be to check the next <MainNode> after each <A> element and ensure it is still the current <MainNode>. You can do this using the generate-id() function.

preceding-sibling::A[generate-id(following-sibling::MainNode[1])=generate-id(current())]

The complete XSLT would look something like follows.

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
   <xsl:output indent="yes"/>

   <xsl:template match="Outer">
           <A>
              <xsl:apply-templates select="MainNode"/>
           </A>
   </xsl:template>
   
   <xsl:template match="MainNode">
       <MainNode>
               <xsl:apply-templates select="preceding-sibling::A[generate-id(following-sibling::MainNode[1])=generate-id(current())]"/>
           </MainNode>
       </xsl:template>
       
       <xsl:template match="A">
            <A1><xsl:apply-templates /></A1>
        </xsl:template>
 
</xsl:stylesheet>

Crass1968 · March 4th, 2010, 07:09 AM

Ok, guys, that has helped me to get started. thank you very much.
Now can I ask if this is possible.... it's like an opposite of the previous question. As a newbie to this stuff, I think my gaffers are trying to confoose me!!!

XML source
<a>

<b1></b1>
<b2></b2>
<b3></b3>
<c>
<c1></c1>
<c2></c2>
</c>
Multiple c-nodes here

</a>

XML Target
<a>
<c>
<c1></c1>
<c2></c2>
</c>
multiple c-nodes here

<b1></b1>
<b2></b2>
<b3></b3>

</a>

mrame · March 4th, 2010, 07:26 AM

try the below:

Code:

<xsl:template match="a">
<xsl:copy>
<xsl:apply-templates select="b/c"/>
<xsl:apply-templates select="b"/>
</xsl:copy>
</xsl:template>
<xsl:template match="c">
<xsl:copy-of select="."/>
</xsl:template>
<xsl:template match="b">
<xsl:copy>
<xsl:copy-of select="* except c"/>
</xsl:copy>
</xsl:template>

mhkay · March 4th, 2010, 07:27 AM

You want a rule for <a> that's along the lines

Code:

<xsl:template match="a">
  <a>
     <xsl:apply-templates select="b/c"/>
     <xsl:apply-templates select="b"/>
  </a>
</xsl:template>

and a template rule for

Code:

<xsl:template match="b">
<b>
  <xsl:apply-templates select="child::node()[not(self::c)]"/>
</b>
</xsl:template>

and everything else can use the identity template

Code:

<xsl:template match="*">
  <xsl:copy>
     <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

samjudson · March 4th, 2010, 07:32 AM

I think it would be best if you spent a little time trying to learn XSLT. I realise that it has got a bit of a learning curve, but once you have got the basics it will help you.

I'd recommend a site such as http://www.w3schools.com/xsl/

Basically you need to write a template to match each element you want to process, and within that template tell it what you want to appear in there.

There is also something called the 'identity template' which will copy all element you don't explicitly call out in other templates.

Code:

<!-- match the 'a' element -->
<xsl:template match="a">
  <!-- copy the 'a' element -->
  <xsl:copy>
  <!-- process the 'b' elements -->
   <xsl:apply-templates select="b"/>
  <!-- then process the 'c' elements -->
   <xsl:apply-templates select="b/c"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="b">
  <xsl:copy>
   <!-- process all inner elements apart from those called 'c' -->
   <xsl:apply-templates select="*[local-name()!='c']"/>
  </xsl:copy>
</xsl:template>

<!-- Identity Template -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>