Make use of default namespaces

kaanyy · June 8th, 2012, 05:03 AM

I am very new to XSLT. Can you share me a link or example to remove namespace prefixes in inner fragments.

Example is displaed below:

<alfa data="abc" xmlns="http://test1.com/">
<mus:beta xmlns:mus="http://test2.com">
<mus:a>1234567897</mus:a>
<mus:s>777666</mus:s>
</mus:beta>
</alfa>

I would like to have:

<alfa data="abc" xmlns="http://test1.com/">
<beta xmlns="http://test2.com">
<a>1234567897</a>
<s>777666</s>
</beta>
</alfa>

Cheers!

Martin Honnen · June 8th, 2012, 05:46 AM

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:mus="http://test2.com"
  exclude-result-prefixes="mus"
  version="1.0">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="mus:*">
  <xsl:element name="{local-name()}" namespace="namespace-uri()}">
     <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

kaanyy · June 8th, 2012, 09:37 AM

Thanks Martin,

Your reply was a big rescue.

Let me write down the change I needed to do on my side due to a syntax error:

Code:

<?xml version='1.0'?>
<xsl:stylesheet
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:mus="http://test2.com"
        exclude-result-prefixes="mus"
        version="1.0">

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="mus:*">
        <xsl:element name="{local-name()}" namespace="{namespace-uri(.)}">
            <xsl:apply-templates select="@* | node()"/>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

note the {namespace-uri(.)} (the dot and { symbol.

Thanks again!

Also for Java developert: Xalan does make a bad transformation with this xsl; however saxon is ok.