fix broken tagging

heinrich1971 · July 23rd, 2016, 08:26 AM

I have some broken tags in my input that I like to fix in my xslt.
I have searched and tried different things, but I can't seem to figure it out.

Input:

Code:

<p>Some text <span class="italic">broken </span><span class="italic">tag</span><span class="italic">s</span> in my content which is <span class="italic">really </span><span class="italic">annoying</span>.</p>

Desired output:

Code:

<p>Some text <span class="italic">broken tags</span> in my content which is <span class="italic">really annoying</span>.</p>

Can someone help me in the right direction?

Martin Honnen · July 23rd, 2016, 08:55 AM

Can you use an XSLT 2.0 processor like Saxon 9? Then it is a task for

Code:

for-each-group group-adjacent

. You will have to explain in more detail what kind of elements you want to merge ( only "span" elements?) to get help with a code sample.

heinrich1971 · July 23rd, 2016, 09:02 AM

Hi Martin,

I use xslt 2.0 and indeed I would only like to merge the span\@italic

Regards
Heinrich

Martin Honnen · July 23rd, 2016, 09:13 AM

If you have access to commercial editions of Saxon 9.6 or 9.7 (for instance with oXygen or Stylus Studio) then you can do it in a generic way with XSLT 3.0 and a composite grouping key in group-ajacent:

Code:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    exclude-result-prefixes="xs math"
    version="3.0">
    
    <xsl:mode on-no-match="shallow-copy"/>
    
    <xsl:template match="p">
        <xsl:copy>
            <xsl:for-each-group select="node()" group-adjacent="node-name(.), @class" composite="true">
                <xsl:copy>
                    <xsl:copy-of select="@class"/>
                    <xsl:apply-templates select="current-group()/node()"/>
                </xsl:copy>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>
    
</xsl:stylesheet>

With XSLT 2.0 you could use a similar approach which concatenates the node-name() and the class attribute for the group-adjacent value, or as you have now posted some details you could use

Code:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    exclude-result-prefixes="xs math"
    version="2.0">
  
    <xsl:template match="@* | node()">
       <xsl:copy>
         <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
   </xsl:template>

    <xsl:template match="p">
        <xsl:copy>
            <xsl:for-each-group select="node()" group-adjacent="self::span and @class = 'italic'">
              <xsl:choose>
                <xsl:when test="current-grouping-key()">
                <xsl:copy>
                    <xsl:copy-of select="@class"/>
                    <xsl:apply-templates select="current-group()/node()"/>
                </xsl:copy>
               </xsl:when>
               <xsl:otherwise>
                  <xsl:apply-templates select="current-group()"/>
               </xsl:otherwise>
              </xsl:choose>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>
    
</xsl:stylesheet>

heinrich1971 · July 24th, 2016, 03:49 AM

Thanks Martin!
This works fine!