Split values and insert some character

bharathidasang · October 11th, 2017, 11:13 AM

Hi,

Can you please anyone help me.

My input:
<root>
<Para0 id="335-100" refid="[335-100]">
<con>Corrections Act 1986 </con>
<sec>Pt 9E, 30G, 30H, 30I, ss 47M, 79H, 104ZC, 104ZD</sec>
</Para0>
</root>
Expected output

<root>
<Para0 id="335-100" refid="[335-100]">
<sec>Pt 9E, Pt 30G, Pt 30H, Pt 30I, ss 47M, ss 79H, ss 104ZC, 104ZD</sec>
</Para0>
</root>

My code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">

<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>

<xsl:template match="Para0">
<xsl:for-each select="//sec">
<sec>
<xsl:for-each select="tokenize(.,',')">

<xsl:variable name="ddd">
<xsl:choose>
<xsl:when test="matches(.,'\s+[A-z]+\s+')">
<xsl:message select="."></xsl:message>
<xsl:analyze-string select="current()" regex="\s+([A-z]+)\s+">

<xsl:matching-substring>
<xsl:value-of select="regex-group(1)"/>
</xsl:matching-substring>
</xsl:analyze-string>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="substring-before(.,' ')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:message select="$ddd"></xsl:message>
<xsl:value-of select="concat($ddd, .)"/><xsl:text>, </xsl:text>

</xsl:for-each>
</sec>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

my output:
<root>
<sec>PtPt 9E, 30G, 30H, 30I, ss ss 47M, 79H, 104ZC, 104ZD, </sec>
</root>

Thanks,
Bharathi

mhkay · December 15th, 2017, 02:07 PM

If you're able to use XSLT 3.0 I would do:

Code:

<xsl:for-each-group select="tokenize(., '\s*,\s*')"
    group-starting-with=".[contains(., ' ')]">
   <xsl:variable name="prefix" select="substring-before(., ' ')"/>
   <xsl:value-of select="head(current-group()), 
                                   tail(current-group())!($prefix||' '||.)"
      separator=","/>
</xsl:for-each-group>

In XSLT 2.0 you can't do group-starting-with on a sequence of atomic values. You could achieve the same effect by first turning the sequence of atomic values into a sequence of text nodes, and then grouping the text nodes.