Tables

andy24 · July 23rd, 2003, 05:59 AM

Can anyone tell me how to put each field of information into a separate cell in a table. I can put all the information in a table containing one row and one cell but I don't want that. I want a row and several cells for each record.
Hopefully this makes sense.
The code is below:

<%
  Dim objRS, objComm, objParam, strType
  Set objComm = Server.Createobject("ADODB.Command")

  objComm.ActiveConnection = strConnect
  objComm.CommandText = "qryMainsDrills"
  objComm.CommandType = adCmdStoredProc

  Set objParam = _
     objComm.CreateParameter("Required Type", adVarChar, adParamInput, 50)
  objComm.Parameters.Append objParam

  strType = "Mains"
  objComm.Parameters("Required Type") = strType

  Set objRS = objComm.Execute

  Set objComm = Nothing
  Set objParam = Nothing

  While Not objRS.EOF
    Response.Write objRS("ProductID") & " " & objRS("Manufacturer") & " " & objRs("ProductDescription") & " " & objRS("ProductCode") & " " & objRS("UnitPrice") & "<BR>"
    objRS.MoveNext
  Wend

  objRS.Close
  Set objRS = Nothing
%>

nidgep · July 23rd, 2003, 06:10 AM

Hi
there are various ways to achieve this, but try the following for starters....

If Not objRS.EOF And Not objRS.BOF Then
  Response.Write "<table width=""100%"" cellpadding=""2"" cellspacing=""2"" border=""1"" >"
'start looping...
While Not objRS.EOF
    Response.Write "<tr>"
    Response.Write "<td>" & objRS("ProductID") & "</td>"
    Response.Write "<td>" & objRS("Manufacturer") & "</td>"
    Response.Write "<td>" & objRs("ProductDescription") & "</td>"
    Response.Write "<td>" & objRS("ProductCode") & "</td>"
    Response.Write "<td>" & objRS("UnitPrice") & "</td>"
    Response.Write "</tr>"
    objRS.MoveNext
  Wend
  Response.Write "</table>"
Else
Response.Write "No data!
"
End If

pgtips · July 23rd, 2003, 06:17 AM

Just change your loop to write out HTML tags like this:

Code:

' create table and column headers
Response.Write("<table>")
Response.Write("<tr><td>ProductID</td><td>Manufacturer</td>etc...</tr>")
While Not objRS.EOF
    ' create a new row for each record
    Response.Write("<tr>")

    ' put each field value inside a <td>
    Response.Write("<td>")
    Response.Write objRS("ProductID")
    Response.Write("</td>")
    Response.Write("<td>")
    Response.Write objRS("Manufacturer")
    Response.Write("</td>")
    ' ... etc

    ' close the row
    Response.Write("</tr>")

    objRS.MoveNext
  Wend

' close the table
Response.Write("</table>")

andy24 · July 23rd, 2003, 11:09 AM

Thanks for your help, everything is sorted now.
Cheers