Starting COM+ Applications

cyad · January 30th, 2004, 12:17 PM

I need to know how to programmatically stop and start a COM+ application. It doesn't necessarily need to be written in VB though. Can this be done? Anything special I need to take into consideration?

Thanks

marcostraf · January 30th, 2004, 02:38 PM

What kind of application is (i.e. Windows server, service etc...)
Marco

pgtips · February 2nd, 2004, 08:26 AM

You can do this easily using the COM+ Admin dll. It can be done in VB or in a script language like VBS (which you can run using WSH). Here's example code:

Code:

On Error Resume Next
    ' if VB add a reference to COM+ 1.0 Admin Type Library.
    ' if VBS just declare this object without a type
    Dim oCatalog As COMAdmin.COMAdminCatalog
    Dim sName As String
    Set oCatalog = CreateObject("COMAdmin.COMAdminCatalog") 

    sName = "the package name goes here"    
    oCatalog.ShutdownApplication sName

    ' to start the app use this syntax
    'oCatalog.StartApplication sName

    If Err.Number = 0 Then
        MsgBox sName & " has been shut down.", vbOKOnly + vbInformation
    Else
        Const cMsg = "Error 0x#ERR# trying to shut down #APP#. (#DESC#.)"
        Dim sMsg
        sMsg = Replace(cMsg, "#ERR#", Hex(Err.Number), 1, 1)
        sMsg = Replace(sMsg, "#APP#", sName, 1, 1)
        sMsg = Replace(sMsg, "#DESC#", Err.Description, 1, 1)
        MsgBox sMsg, vbOKOnly + vbInformation
        Err.Clear
    End If
    Set oCatalog = Nothing

hth
Phil

cyad · February 2nd, 2004, 11:44 AM

Thanks alot. This seems to be what I need.

dragon100 · September 2nd, 2004, 05:09 AM

is there any way to actually start and stop com+ packages on a different server through an IP address?

If any one can make changes to this script would be much appreciated:

Dim oApplications 'As COMAdminCatalogCollection
    Dim oCatalog 'As COMAdminCatalog
    Dim oApp 'As COMAdminCatalogObject

    Set oCatalog = CreateObject("ComAdmin.COMAdminCatalog")
    Set oApplications = oCatalog.GetCollection("Applications")
    oApplications.Populate

    Wscript.Echo "Now Closing Tranzax Communications All Users Will Be Looged Off And Unable To Log In."
    For Each oApp In oApplications
        If oApp.Name = "Tranzax" Then
        Wscript.Echo "Shutting down " & oApp.Name, vbOKOnly + vbInformation
            Call oCatalog.ShutdownApplication(oApp.Name)

        End If
    Next 'oApp

    Wscript.Echo "Completed Shutdown Process Of Tranzax Now Exiting"

    Set oApp = Nothing
    Set oApplications = Nothing
    Set oCatalog = Nothing

pgtips · September 2nd, 2004, 06:46 AM

See http://msdn.microsoft.com/library/en...fRemoteWSH.asp for details of how to use remote scripting to run that script against a different server.

hth
Phil