I've got an XML document that has a SOAP wrapper around it:

<?xml version="1.0" encoding="UTF-8" ?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <SOAP-ENV:Body>
        <FirstNode>
            <SecondNode>
                <Children />
            </SecondNode>
        </FirstNode>
    </SOAP-ENV:Body>
</SOAP-ENV:Envelope>

I'd like to use XSL to copy the <SecondNode> and all the <Children> and remove the SOAP wrapper to create a new XML document.

I've tried this:

<xsl:template match="//FirstNode/node()">
        <NewFirstNode>
            <xsl:copy-of select="."/>
        </NewFirstNode>
</xsl:template>

But it puts the namespace on the <SecondNode> like this:

<SecondNode xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">

Any ideas why? I'd appreciate any tips. Thanks.

xsl:copy-of is defined to copy all the in-scope namespaces of the element being copied, because the XSLT processor has no way of knowing which of them might be needed (by prefix-sensitive element or attribute content).

XSLT 2.0 has an option copy-namespaces="no" designed explicitly for this use case.

In 1.0 you need a variant of the identity template that copies elements without their namespaces:

<xsl:template match="*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </
</

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Thanks for the reply. Would I replace what I have above with this?

<xsl:template match="//FirstNode/node()">
        <NewFirstNode>
            <xsl:element name="{name()}" namespace="{namespace-uri()}">
                <xsl:copy-of select="@*" />
                <xsl:apply-templates />
            </xsl:element>
        </NewFirstNode>
</xsl:template>

At present this returns an empty FirstNode with no children elements.

No, use the code exactly as written, and replace

<xsl:template match="//FirstNode/node()">
        <NewFirstNode>
            <xsl:copy-of select="."/>
        </NewFirstNode>
</xsl:template>

with

<xsl:template match="FirstNode">
        <NewFirstNode>
            <xsl:apply-templates/>
        </NewFirstNode>
</xsl:template>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

I tried that but it still copies the whole source document and leaves the namespace on the 1st element.

Here's my third attempt which I think is very close:

<xsl:template match="*[not(namespace-uri())]">
    <xsl:element name="{local-name(.)}">
        <xsl:copy-of select="@*[local-name() != 'xmlns']" />
        <xsl:apply-templates />
    </xsl:element>
</xsl:template>
<xsl:template match="/">
    <NewFirstNode>
       <xsl:apply-templates select="//FirstNode/SecondNode/node()" />
    </NewFirstNode>
</xsl:template>

This give me the exact structure that i'm after and all the child nodes are present. The only issue is that none of the data is present in the transformed XML.

Is there anything obvious that might be preventing this?

Hi Mike,

On page 196 of the WROX XSLT 2nd Edition Programmer's Reference <xsl:copy-of > is defined.

Under the Content heading it says, "None; the element is always empty"

Does this mean what I am trying to achieve above is not possible? i.e. I won't be able to get the element and children element values in my transformed XML.

Cheers,
Francis

No, what that is saying is that you can't write things like

<xsl:copy-of select="xyz">
  <something-here/>
</xsl:copy-of>

It's not saying that any elements written to the result tree will be empty - on the contrary, they will be exact copies of the elements you are copying.

However, here you don't want an exact copy. You want a copy of the tree minus its namespaces. Remember that in the tree model which XSLT sees, every namespace declaration is effectively copied to every element that it applies to, and you want to copy the tree without these namespaces. The way to do that is the way you were shown in a previous reply.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Unfortunately that didn't work.

I don't know why you're making such a meal of this. This stylesheet:

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8"
indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:element>
</xsl:template>

<xsl:template match="/">
  <xsl:apply-templates select="//SecondNode"/>
</xsl:template>

</xsl:stylesheet>

applied to this document:

<?xml version="1.0" encoding="UTF-8" ?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <SOAP-ENV:Body>
        <FirstNode>
            <SecondNode>
                <Children />
            </SecondNode>
        </FirstNode>
    </SOAP-ENV:Body>
</SOAP-ENV:Envelope>

produces this output:

<?xml version="1.0" encoding="UTF-8"?>
<SecondNode>
   <Children/>
</SecondNode>

Which part of it doesn't work?

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

Mea culpa.

<xsl:template match="text()">

</xsl:template>

Was at the bottom of my stylesheet!!!

Thanks for your help.