Hi, new to the forum and xslt.

XSLT:

<?xml version="1.0" encoding="utf-16" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns="http://ACORD.org/Standards/Life/2">
    <xsl:output method="xml"/>


    <xsl:template match="/ns:TXLife/ns:UserAuthRequest/ns:UserPswd/ns:Pswd">
            &lt;<xsl:value-of select="name()"/>&gt;<xsl:value-of select="99999999"/>&lt;/<xsl:value-of select="name()"/>&gt;
    </xsl:template>

     <xsl:template match="*">
         &lt;<xsl:value-of select="name()"/>&gt;
         <xsl:apply-templates select="*"/>
         <xsl:value-of select="text()"/>
         &lt;/<xsl:value-of select="name()"/>&gt;
    </xsl:template>
</xsl:stylesheet>

I'm trying to accomplish a simple task: Create a near-copy of an XML document, but substitute some values in the transformation.

It seems to be a decent start, but I have two questions:

1) in the "*" template, until I added 'select="*"' to the apply-templates, the text in my nodes was duplicated. Not where I create the tags, just the text:

         &lt;ns:UserTime&gt;
         14:33:11-06:0014:33:11-06:00
         &lt;/ns:UserTime&gt;

After adding the select, works as expected. If it were processing the 'UserTime' node twice, why didn't I get the tags twice as well? Clearly something about recursion I'm not seeing.

2) Can someone point me in a direction to ensure the attributes of nodes are copied over as well?

Thanks a million. I've enjoyed reading/using the forum and books.

Don't try to create markup by hand. Create element nodes (using xsl:element for example) and let the serializer do the markup for you.

You've sort-of reinvented the important concept of the identity template by yourself, congratulations. I usually write it as:

<xsl:template match="*">
  <xsl:copy>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

which I suspect will meet your needs better.

Doing

    <xsl:apply-templates select="*"/>
    <xsl:value-of select="text()"/>

seems a bad idea as it will process all the child elements, then all the child text nodes, which loses the order if elements and text nodes are mixed together. Doing <xsl:apply-templates select="node()"/> (which is the default with no select) does the same thing but retains the order.

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference