XML to XML using XSLT

xslt_wiz · August 7th, 2006, 09:52 AM

I have a repeting XMl input
 <ServiceAttributeList>
 <ServiceAttribute>
 <Name> xyz </Name>
 <Value>123</Value>
 </ServiceAttribute>
 <ServiceAttribute>
 <Name>abc</Name>
 <Value>4566</Value>
 </ServiceAttribute>
 </ServiceAttributeList>
 <ServiceAttributeList>
 .....
 </ServiceAttributeList>

I want to transorm it into

 <ServiceAttributeList>
 <ServiceAttribute>
 <xyz>
 <Value>123</Value>
 </xyz>
 </ServiceAttribute>
 <ServiceAttribute>
 <abc>
 <Value>4566</Value>
 </abc>
 </ServiceAttribute>
 </ServiceAttributeList>

 <ServiceAttributeList>
 ................
 </ServiceAttributeList>

what XSLT i have to write? any helps?

mhkay · August 7th, 2006, 11:57 AM

Something like

<xsl:template match="ServiceAttribute">
<xsl:element name="{Name}">
<xsl:copy-of select="Value"/>

Michael Kay
http://www.saxonica.com/
Author, XSLT Programmer's Reference and XPath 2.0 Programmer's Reference

xslt_wiz · August 7th, 2006, 10:54 PM

Thanks Buddy..But i need the 'copy of' input xml to out put with the changes I mentioned.

xslt_wiz · August 8th, 2006, 08:13 AM

Output and input should look similar except for all Name value attributes.

Input
 <ServiceAttributeList>
 <ServiceAttribute>
 [u]<Name> xyz </Name>
 [u]<Value>123</Value>
 </ServiceAttribute>
 <ServiceAttribute>
 [u]<Name>abc</Name>
 [u]<Value>4566</Value>
 </ServiceAttribute>
 </ServiceAttributeList>
 <ServiceAttributeList>
 .....
 </ServiceAttributeList>

output
 <ServiceAttributeList>
 <ServiceAttribute>
 [u]<xyz>
 [u]<Value>123</Value>
 [u]</xyz>
 </ServiceAttribute>
 <ServiceAttribute>
 [u]<abc>
 [u]<Value>4566</Value>
 [u]</abc>
 </ServiceAttribute>
 </ServiceAttributeList>

 <ServiceAttributeList>
 ................
 </ServiceAttributeList>

Thanks

xslt_wiz · August 9th, 2006, 12:16 AM

Any Help on this?

joefawcett · August 9th, 2006, 02:47 AM

I think Michael showed the solution but if you need more help you need to give us an accurate representation of your input XML. The example you gave is not well-formed as it has no document element.

Personally I think the first XML is a better representation. It's easier to manipulate and also can you guarantee that the text of the Name element will form a legitimate XML element name?

--

Joe (Microsoft MVP - XML)

xslt_wiz · August 9th, 2006, 04:09 AM

It will alomost look like one below

<?xml version="1.0" encoding="UTF-8"?>
<SPRequestMessage xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
 <SPRequestSequence>
 <SPRequest>
 <SPRequestID>1</SPRequestID>
 <Action>Create</Action>
 <ServiceType>Create-VoIP-Service</ServiceType>
 <LocationID/>
 <ServiceAttributeList>
 <ServiceAttribute>
 <Name>voipId</Name>
 <Value>123</Value>
 </ServiceAttribute>
 <ServiceAttribute>
 <Name>subsId</Name>
 <Value>1235</Value>
 </ServiceAttribute>
 </ServiceAttributeList>
 </SPRequest>
 </SPRequestSequence>
</SPRequestMessage>

and the output will be like

<?xml version="1.0" encoding="UTF-8"?>
<SPRequestMessage xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
 <SPRequestSequence>
 <SPRequest>
 <SPRequestID>1</SPRequestID>
 <Action>Create</Action>
 <ServiceType>Create-VoIP-Service</ServiceType>
 <LocationID/>
 <ServiceAttributeList>
 <ServiceAttribute>
 <voipId>
 <Value>123</Value>
 </voipId>
 </ServiceAttribute>
 <ServiceAttribute>
 <subsId>
 <Value>1235</Value>
 </subsId>
 </ServiceAttribute>
 </ServiceAttributeList>
 </SPRequest>
 </SPRequestSequence>
</SPRequestMessage>

joefawcett · August 9th, 2006, 07:59 AM

Okay, you start with the identity template:

Code:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

and then add the template Michael showed to form the new style ServiceAttribute element:

Code:

  <xsl:template match="ServiceAttribute">
    <ServiceAttribute>
      <xsl:element name="{Name}">
        <xsl:copy-of select="Value"/>
      </xsl:element>
    </ServiceAttribute>
  </xsl:template>

This gives the full stylesheet as:

Code:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ServiceAttribute">
    <ServiceAttribute>
      <xsl:element name="{Name}">
        <xsl:copy-of select="Value"/>
      </xsl:element>
    </ServiceAttribute>
  </xsl:template>
</xsl:stylesheet>

--

Joe (Microsoft MVP - XML)

xslt_wiz · August 9th, 2006, 08:44 AM

Thanks very much
It is working well.
Merci encore.

shakthi26 · July 17th, 2013, 09:11 AM

This is all about reverse a string. It works properly for the given Value 'ABCDEF'. The output is also correct 'FEDCBA'. But I want to know how this is printing letters 'A' and 'D' in this string. Could anyone help me to understand this? please. Elaborate this working method.

Code:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
<xsl:output method="html"/>
<xsl:template name="reverse">
<xsl:param name="input" select="'ABCDEF'"/>
<xsl:variable name="len" select="string-length($input)"/>
<xsl:choose>
<xsl:when test="$len &lt; 2">
<xsl:value-of select="$input"/>
</xsl:when>
<xsl:when test="$len = 2">
<xsl:value-of select="substring($input,2,1)"/>
<xsl:value-of select="substring($input,1,1)"/>
</xsl:when>
<xsl:otherwise>
<xsl:variable name="mid" select="floor($len div 2)"/>
<xsl:call-template name="reverse">
<xsl:with-param name="input" select="substring($input,$mid+1,$mid+1)"/>
</xsl:call-template>
<xsl:call-template name="reverse">
<xsl:with-param name="input" select="substring($input,1,$mid)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="/">
<xsl:call-template name="reverse">
</xsl:call-template>
</xsl:template>
</xsl:stylesheet>