Using of correct XPATH to recognize arributes

ROCXY · April 28th, 2009, 07:40 AM

Hi All,

Here below is an help request to recognize attributes @type @before @after

Input XML

<text>para goes here â¦â¦â¦â¦â¦.

<list type="arabic" before="(" after=")">
<li><text>item 1 <footref id="13"/>;</text></li><li><text> item 2 <footref id="14"/>;</text></li>
</list>

Required XML

<ol>
<li>(1)  item 1 13;</li>
<li>(2)  item 2 14;</li>
</ol>

Used XSL

<xsl:template match="*/list"><xsl:text>
</xsl:text><xsl:element name="list"><xsl:attribute name="type">1</xsl:attribute><xsl:value-of select="."/></xsl:element></xsl:template>

Any Help would be grateful.

Martin Honnen · April 28th, 2009, 08:05 AM

Assuming you want to transform

Code:

<list type="arabic" before="(" after=")">
<li><p><text>item 1 <footref id="13"/>;</text></p></li><li><p><text> item 2 <footref id="14"/>;</text></p></li>
</list>

to

Code:

<ol>

   <li>(1)  item 1 <sup>13</sup>;</li>
   <li>(2)   item 2 <sup>14</sup>;</li>

</ol>

then the following stylesheet does that:

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="list">
    <ol>
      <xsl:apply-templates/>
    </ol>
  </xsl:template>
  
  <xsl:template match="li">
    <xsl:copy>
      <xsl:value-of select="../@before"/>
      <xsl:number/>
      <xsl:value-of select="../@after"/>
      <xsl:text>  </xsl:text>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="footref">
    <sup>
      <xsl:value-of select="@id"/>
    </sup>
  </xsl:template>

</xsl:stylesheet>

RICHBIRD · April 28th, 2009, 10:36 AM

Use This Code:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="xml"/>

<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="title">
<xsl:element name="title"><xsl:apply-templates/></xsl:element>
</xsl:template>

<xsl:template match="list">
<xsl:variable name="listyp"><xsl:value-of select="@type"/></xsl:variable>
<xsl:choose>
<xsl:when test="$listyp='arabic'">
<xsl:element name="ol"><xsl:apply-templates/></xsl:element>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="li">
<xsl:variable name="lisbf" select="../@before"/>
<xsl:variable name="lisaf" select="../@after"/>
<xsl:element name="li">
<xsl:value-of select="$lisbf"/><xsl:number/><xsl:value-of select="$lisaf"/>
<xsl:text disable-output-escaping ='yes'>&nbsp;&nbsp;</xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>

<xsl:template match="footref">
<xsl:element name="sup">
<xsl:value-of select="@id"/>
</xsl:element>
</xsl:template>

</xsl:stylesheet>

ROCXY · April 29th, 2009, 04:13 AM

Thanks a lot Honnen and Richbird, It is very use full! Similarly How do I update XSLT when I come across other list type lilke (alpha, roman etc.,) Kindly advice Let us assume following exhibits.

Input Code:
<list type="arabic" before="(" after=")">

<li><text>item 1</text></li>
<li><text>item 2</text>

<list type="alpha" before="[" after="]">
<li><text>Sub item 1</text></li>
<li><text>Sub item 2</text></li>
</list>
</li>
</list>

Required Output:

<ol>

<li>(1) item 1 </li>
<li>(2) item 2
<ol>
<li>(a)Sub item 1</li>
<li>(b)Sub item 2</li>
</ol>
</li>
</ol>

Thanks once again! For your promt response.

RICHBIRD · April 29th, 2009, 04:30 AM

Use this code for different type of list

1.
<xsl:number format="a"/>
for
<li>(a)  item 1 13;</li>
<li>(b)   item 2 14;</li>

2.
<xsl:number format="A"/>
for
<li>(A)  item 1 13;</li>
<li>(B)   item 2 14;</li>

3.
<xsl:number format="i"/>
for
<li>(i)  item 1 13;</li>
<li>(ii)   item 2 14;</li>

4.
<xsl:number format="I"/>
for
<li>(I)  item 1 13;</li>
<li>(II)   item 2 14;</li>

5.
<xsl:number format="01"/>
for
<li>(01)  item 1 13;</li>
<li>(02)   item 2 14;</li>

ROCXY · April 29th, 2009, 04:35 AM

Thanks Richbird.

How that can be checked using <xsl:when> when both(arabic and alpha) comes together! has shown above in the exhibit???? - Please check and advice,.

RICHBIRD · April 29th, 2009, 04:57 AM

<xsl:template match="li">
<xsl:variable name="listype" select="../@type"/>
<xsl:variable name="lisbf" select="../@before"/>
<xsl:variable name="lisaf" select="../@after"/>
<xsl:element name="li"><xsl:value-of select="$lisbf"/>
<xsl:choose>
<xsl:when test="$listype='arabic'">
<xsl:number format="1"/>
</xsl:when>
<xsl:when test="$listype='alpha'">
<xsl:number format="a"/>
</xsl:when>
<xsl:otherwise>
<xsl:number/>
</xsl:otherwise>
</xsl:choose>
<xsl:value-of select="$lisaf"/>
<xsl:text disable-output-escaping ='yes'>&nbsp;&nbsp;</xsl:text>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>

ROCXY · April 29th, 2009, 05:17 AM

Thanks a Lot Richbird