how to get siblings and parents

eruditionist · June 28th, 2011, 06:37 PM

I know how to go from top down in a nested xsl using xsl:for-each but need to know how to traverse back up for instance here is my XML

<?xml version="1.0" encoding="UTF-8"?>
<root>
<business>
<node show="true">
<label key="">B1</label>
<link type="page">
<value>B1</value>
</link>
<node show="true">
<label key="">B1 Level two </label>
<link type="page">
<value>b1_level_two.aspx</value>
</link>
<node show="true">
<label key="">B1 level three</label>
<link type="page">
<value>b1_level_three.aspx</value>
</link>
</node>
<node show="true">
<label key="">B1 Level three X</label>
<link type="page">
<value>b1_level_theex.aspx</value>
</link>
<node show="true">
<label key="">B1 Level Four</label>
<link type="page">
<value>b1_level_four.aspx</value>
</link>
</node>
</node>
<node show="true">
<label key="">B1 Level three XX</label>
<link type="page">
<value>b1_level_theexx.aspx</value>
</link>
</node>
</node>
<node show="true">
<label key="">B1 level two X</label>
<link type="page">
<value>b1_level_twox.aspx</value>
</link>
</node>
</node>
</business>
</root>

based on this xml if
//value='b1_level_theex.aspx'

or if this is provided

//value='b1_level_four.aspx'

I need this to be printed.

<level1> B1 <level1>
<level2> B1 Level two <level2>
<level3> B1 level three <level3>
<level3> B1 Level three X<level3>

so it will only display upto 3 levels doesnt matter how many node deep the value exists. same ways if //value='B1' than I want level 1 and 2 to be printed only.

samjudson · June 29th, 2011, 03:18 AM

Something along the lines of this would do the job I hope:

Code:

   <xsl:template match="/">
      <xsl:apply-templates select="//node[link/value='b1_level_four.aspx']"/>
   </xsl:template>

   <xsl:template match="node">
      <xsl:apply-templates select="ancestor::node[1]"/>
      <xsl:element name="level{count(ancestor::node)+1}">
         <xsl:value-of select="label"/>
      </xsl:element>
   </xsl:template>

eruditionist · June 29th, 2011, 10:19 AM

This works but how do I exclude <level4>?

<?xml version='1.0' ?>
<level1>B1</level1><level2>B1 Level two </level2><level3>B1 Level three X</level3><level4>B1 Level Four</level4>

It should only print till level3.

samjudson · June 29th, 2011, 12:15 PM

Then use ".." to get the parent of the node you are selecting:

Code:

<xsl:apply-templates select="//node[link/value='b1_level_four.aspx']/.."/>

Martin Honnen · June 29th, 2011, 12:25 PM

The following should output three levels, controled by the parameter named "depth":

Code:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  
  <xsl:param name="value" select="'b1_level_four.aspx'"/>
  <xsl:param name="depth" select="3"/>
  
  <xsl:output indent="yes"/>
  
   <xsl:template match="/">
      <xsl:apply-templates select="//node[link/value = $value]/ancestor::node[position() &lt;= $depth]"/>
   </xsl:template>

   <xsl:template match="node">
      <xsl:element name="level{count(ancestor::node)+1}">
         <xsl:value-of select="label"/>
      </xsl:element>
   </xsl:template>
   
</xsl:stylesheet>

eruditionist · June 29th, 2011, 01:13 PM

given the following xml is there a way to find if the current node is a parent or grandparent node for instance if I looped through the first set of nodes.

<xsl:for-each select="root/business/node">
<xsl:choose>
<xslwhen test="check all nodes under this to see if value='b1_level_four.aspx exists'">
TRUE
</xsl:when>
<xsl:otherwise>
FALSE
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>

Martin Honnen · June 29th, 2011, 01:19 PM

Code:

<xsl:when test="descendant::value[. = '...']">

eruditionist · June 29th, 2011, 03:00 PM

You guys are awesome. Thanks. It worked