Have recently migrated our application from Win NT to Win 2003. SMTP server is not sending out emails. Made some code changes. But surprisingly, there is no errors, which makes it more harder to trace the problem. Any assistance is appreciated. My codes are below.


************************************************** *****************
Dim objMail
 MsgBox ("Test6b")
    'Set objMail = Server.CreateObject("CDO.Message")
    Set cdoMessage = Server.CreateObject("CDO.Message")
     MsgBox ("Test6c")

    objMail.From = strFrom
    objMail.To = strRecipient
    objMail.Subject = strSubject
    objMail.TextBody = strMessage

    'Send the email
    objMail.Send

    'Clean-up mail object
    Set objMail = Nothing

Is that you are using SERVER.CREATEOBJECT in VBSCRIPT? Or is that you are using this code in an ASP file?

If that is just a VBSCRIPT file, then remove SERVER keyweod from there. Just CreateObject is enough. That should be what you are missing.

Hope that helps.
Cheers!

_________________________
- Vijay G
Strive for Perfection

I use this code to send email into our email group using an anonymous account...

Const cdoBasic = 1 'basic (clear-text) authentication

Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Subject Line"
objMessage.Sender = "user@emaildomain.xxx"
objMessage.To = "recipient@emaildomain.xxx"
objMessage.TextBody = "Message text..."

'==This section provides the configuration information for the remote SMTP server.

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.emaildomain.xxx"

'Type of authentication, NONE, Basic (Base64 encoded), NTLM
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

'Your UserID on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = "****"

'Your password on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "****"

'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

'Use SSL for the connection (False or True)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

objMessage.Configuration.Fields.Update


mmcdonal

Hi md_haris,

Has that issue been resolved?

Cheers!

_________________________
- Vijay G
Strive for Perfection