Transforming attribute with several values

moggi · August 19th, 2010, 10:12 PM

Hello,

i have a xml-file, that looks like that:

Code:

<?xml version="1.0" encoding="ISO-8859-1"?>
<aa>
	<bb id="b1" name="ex1"/>
	<bb id="b2" name="ex2"/>
	<bb id="b3" ref="b1 b2" name="ex3"/>
</aa>

the result should look like this file:

Code:

<?xml version="1.0" encoding="ISO-8859-1"?>
<aa>
	<cc name="ex1"/>
	<cc name="ex2" ref="//aa/ex1"/>
	<cc name="ex3" ref="//aa/ex1 //aa/ex2"/>
</aa>

My problem is that the ref attribute contains several values, which should be transformed. Each value represents an object. I tried to transform it with Saxon 9.1, but it complains if i try the following transformation:

Code:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://example.com" version="2.0">
	<xsl:output method="xml" encoding="ISO-8859-1" />
	
	<xsl:template match="//bb">
	<bb name="./@name">
		<xsl:attribute name="ref">
			<xsl:for-each select="tokenize(./@ref, ' ')">
				//aa/<xsl:value-of select="//bb[@id=.]//@name"/>
			</xsl:for-each>
		</xsl:attribute>
	</bb>
	</xsl:template>
	
</xsl:stylesheet>

Is there a solution to this problem?

samjudson · August 20th, 2010, 02:37 AM

A couple of things.

Firstly, you have a lot of use of "//" - in my opinion overuse. This will always slow down your XSLT - more so the larger the XML input. Don't use it unless you need to. It's definitely not needed in the template match property.

Secondly, inside the for-each instruction the current context is an atomic value (a string), so the "//" at the start of the xpath has no meaning, because it tries to find all nodes in the current context - and you can't for this in an atom value.

Thirdly, in the [@id=.] predicate the "." refers to the current element - inside the xpath, i.e. the parent bb element you are searching, not the string value returned by the tokenize.

Taking all those points the following is an example that does what you want:

Code:

	  <xsl:variable name="aa" select="/aa"/>
	
       <xsl:template match="bb">
       <bb name="{@name}">
               <xsl:attribute name="ref">
                       <xsl:for-each select="tokenize(@ref, ' ')">
                               <xsl:text>//aa/</xsl:text>
                               <xsl:value-of select="$aa/bb[@id=current()]/@name"/>
                               <xsl:text> </xsl:text>
                       </xsl:for-each>
               </xsl:attribute>
       </bb>
       </xsl:template>

mhkay · August 20th, 2010, 04:00 AM

Or for a more concise version

Code:

       <xsl:variable name="aa" select="/aa"/>
	
       <xsl:template match="bb">
       <bb name="{@name}"
             ref="{for $t in tokenize(@ref, ' ') 
                     return concat('//a/', $aa/bb[@id=$t]/@name}"/>
       </xsl:template>

moggi · August 20th, 2010, 09:22 PM

Thank you. It works fine.

I used "//" because it's just a simplified example. In my project I don't know exactly where my "bb" are.

samjudson · August 21st, 2010, 05:26 AM

It doesn't matter - you don't need the // in a match statement to match a template against a "bb" element anywhere in the input xml.